Previously we showed you how to replicate the well known formmail.pl. If you haven't read that article you may do so by clicking here.

Here we extend the functionality of that script by allowing the inclusion of a file.

Full support for use of these scripts is given free of charge to existing hosting customers.

Firstly create a file called fileformmail.asp and copy the following code into it.

<%
' formmail.asp by Duane Jackson 30/11/2004 duane[at]keyone.co.uk
'
'Put a form on your webpage with the action set to point to this file and the method set to POST
'The form should contain two hidden fields. The first should be called 'subject' and contain the value
'hat you wish to appear in the email subject line. The second should be called 'redir' and the value
'should contain the URL you want to redirect the user to once the email has been sent. This may be a thanks page.
'
'Finally, edit the details below to set the sender and recipient details, and the text you want to use as
'an introduction to the email. Change continueOnErrors  to 'true' if you want any errors to be ignored.

	sSenderAddress = "formmail@yourdomain.com"
	sSenderName = "FormMail"
	sRecipientName = "Your Name "
	sRecipientAddress="you@yourdomain.com"
	sIntroText = "The details below were sent via your website:"
	continueOnErrors =  false
	sSavePath = "e:\wwwroot\yourdomain.com\uploads"

' Thats all! Don't edit below this line unless you know what you are doing.

	if continueOnErrors then on error resume next
	Dim mySmartMail
	Set mySmartMail = Server.CreateObject("aspSmartMail.SmartMail")
	mySmartMail.Server = "mail01.leetmail.net"
	mySmartMail.SenderName = sSenderName
	mySmartMail.SenderAddress = sSenderAddress
	mySmartMail.Recipients.Add sRecipientAddress, sRecipientName
	
	Set Upload = Server.CreateObject("ASPUploadComponent.cUpload")
	
	sRedir = upload.Form("redir").value
	mySmartMail.Subject = upload.Form("subject").value

	For i = 1 to upload.count
		FormItem = upload.form(i).name
  		if lcase(FormItem) <> "redir" AND lcase(FormItem) <> "subject" AND lcase(FormItem) <> "file" AND lcase(FormItem) <> "submit" then sBody = sBody &  FormItem & ": " &  upload.Form(FormItem).value & vbcrlf
	Next

	mySmartMail.Body  =  sIntroText & vbcrlf & vbcrlf & sBody

	if upload.fieldExists("file") then 
		bHaveFile = true
		sFilePath = upload.form("file").value
		sExt=right(sFilePath,3)
		sFileName = session.SessionID & "." & sExt
		upload.Form("file").SaveFile sSavePath,  sFileName
		mySmartMail.Attachments.Add sSavePath & "\" & sFileName
	end if
	mySmartMail.SendMail
	set mySmartMail = nothing
	set upload = nothing
	if bHaveFile then
		set fso=server.CreateObject("scripting.filesystemobject")
		fso.deletefile sSavePath &  "\" & sFileName
		set fso = nothing
	end if
	
	response.redirect  sRedir
	%>

Read the editing instructions at the top of the file to set sender and recipient email addresses, etc. Save the file and upload it to your web space.

Now to create the form that users will see. An example of the form is given below.

<form action="fileformmail.asp" method="post" enctype="multipart/form-data"  name="form1" onSubmit="checkReg(); return false;">
  <input type="hidden" name="subject" value="Registration submission details from the website">
<input type="hidden" name="redir" value="thanks.html">
  <br>
  First Name: 
  <input type="text" name="firstname"><br>
  Last Name: 
  <input type="text" name="lastname">
  <br>
  <input type="file" name="file">
  <br>
  <input type="submit" name="Submit" value="Submit">
</form>

Upload the page containing your form and try it out. The email will get sent regardless of whether or not there is a file to include. Further error handling and customization could be added if required. If you would like to customised this script but don't have the necessary skills please contact us to discuss your needs.

If your are a client of Key One and you are having problems getting this script to work then please contact your account manager or email support@keyone.co.uk.